// Joshua
//
//  A simple vector font routine and a "War Games"-like interface thingy.
//
//  left-click on the screen to increase the number of characters in the code it got
//  right-click to decrease


byte fixed[] = { 'C', 'P', 'E', '1', '7', '0', '4', 'T', 'K', 'S' }; /* the launch code */
int thresh[] = { 4, 8, 6, 7, 2, 5, 3, 0, 9, 1 }; /* the order that Joshua gets the numbers */

int clickLevel = 0;

void setup()
{
  size( 600, 400 );
  //size( screen.width, screen.height ); // use this for "fullscreen".. shift-command-r to "present" it fullscreen
  frameRate( 15 );
  smooth();
}
int c=0;
int blinkCounter=0;

void draw()
{
  background( 0 );
  noFill();
  glowbox( 20, 20, width-40, height-40 );
  
  byte display[] = new byte[10];
  if( clickLevel <= thresh[0] ) display[0] = (byte)random( 'a', 'z' ); else display[0] = fixed[0];
  if( clickLevel <= thresh[1] ) display[1] = (byte)random( 'a', 'z' ); else display[1] = fixed[1];
  if( clickLevel <= thresh[2] ) display[2] = (byte)random( 'a', 'z' ); else display[2] = fixed[2];

  if( clickLevel <= thresh[3] ) display[3] = (byte)random( '0', '9' ); else display[3] = fixed[3];
  if( clickLevel <= thresh[4] ) display[4] = (byte)random( '0', '9' ); else display[4] = fixed[4];
  if( clickLevel <= thresh[5] ) display[5] = (byte)random( '0', '9' ); else display[5] = fixed[5];
  if( clickLevel <= thresh[6] ) display[6] = (byte)random( '0', '9' ); else display[6] = fixed[6];

  if( clickLevel <= thresh[7] ) display[7] = (byte)random( 'a', 'z' ); else display[7] = fixed[7];
  if( clickLevel <= thresh[8] ) display[8] = (byte)random( 'a', 'z' ); else display[8] = fixed[8];
  if( clickLevel <= thresh[9] ) display[9] = (byte)random( 'a', 'z' ); else display[9] = fixed[9];

  String code = new String( display );

  if( clickLevel >= 10 ) /* after it got all 10 numbers... */
  {
    blinkCounter++;
    if( blinkCounter > 10 ) /* on for 10 frames */
    {
      if( blinkCounter > 15 ) /* off for 15-10 frames */
        blinkCounter = 0;
      return;
    }
  }

  /* draw out the code, first big, transparent...*/
  float sf = (width/10)/7;
  strokeWeight( 6 );
  stroke( 200, 255, 255, 128 );
  vectorText( code, int((width - sf*5.9*10)/2), int((height - sf*8)/2), 0, sf );

  /* then smaller, opaque */
  strokeWeight( 2 );
  stroke( 200, 255, 255 );
  vectorText( code, int((width - sf*5.9*10)/2), int((height - sf*8)/2), 0, sf );
}

/* draw the outer glowing border */
void glowbox( int x, int y, int w, int h )
{
  int stk = 4;
  noFill();
  for( int i=4 ; i>0 ; i-- )
  {
    stroke( 255/i );
    strokeWeight( 4*i );
    rect( x, y, w, h );
  }
}

void mousePressed()
{
  if( mouseButton == LEFT ) clickLevel++;
  if( mouseButton == RIGHT ) clickLevel--;
  clickLevel = constrain( clickLevel, 0, 10 );
}

/* print a vector string */
void vectorText( String s, int x, int y, int kern, float sc )
{
  pushMatrix();
  translate( x, y );
  for( int i=0 ; i<s.length() ; i++ )
  {
    pushMatrix();
    translate( sc * (6*(i+kern)), 0 );
    vectorGlyph( s.toUpperCase().charAt( i ), sc );
    popMatrix();
  }
  popMatrix();
}

/* this draws a character at the current x, y with the desired scale factor */
void vectorGlyph( char ch, float sc )
{
  /* find the glyph */
  int g = 0;
  boolean found = false;
  while( !found && glyphs[g][0] != 0 )
  {
    if( glyphs[g][0] == ch )
      found = true;
    else
      g++;
  }
  if( !found ) return;

  /* draw the glyph */
  int px=0, py=0, nx=0, ny=0;
  int idx = 1;
  boolean newLine = true;
  while( glyphs[g][idx] != -2 )
  {
    if( newLine ) {
      px = glyphs[g][idx++];
      py = glyphs[g][idx++];
      newLine = false;
    }
    if( glyphs[g][idx] == -2 ) {
      /* do nothing */
    } else if( glyphs[g][idx] == -1 ) {
      newLine = true;
      idx++;
    } else {
      nx = glyphs[g][idx++];
      ny = glyphs[g][idx++];
      line( px*sc, py*sc,  nx*sc, ny*sc );
      px = nx;
      py = ny;
    }
  }
}

/* the following is *really close* to what was used in the movie "War Games".
   There are a few discrepancies here and there, but nothing that anyone would ever notice.
*/
int glyphs[][] = 
{
  { 'A',  0, 8,  0, 1,  1, 0,  3, 0,  4, 1,  4, 8,  -1,  0, 4,  4, 4,  -2 },
  { 'B',  0, 0,  3, 0,  4, 1,  4, 3,  3, 4,  4, 5,  4, 7,  3, 8,  0, 8,  0, 0,  -1,  0, 4,  3, 4,  -2 },
  { 'C',  4, 1,  3, 0,  1, 0,  0, 1,  0, 7,  1, 8,  3, 8,  4, 7,  -2 },
  { 'D',  0, 0,  3, 0,  4, 1,  4, 7,  3, 8,  0, 8,  -1,  1, 0,  1, 8, -2 },
  { 'E',  4, 0,  0, 0,  0, 8,  4, 8,  -1,  0, 4,  2, 4, -2 },
  { 'F',  4, 0,  0, 0,  0, 8,  -1,  0, 4,  2, 4,  -2 },
  { 'G',  4, 1,  3, 0,  1, 0,  0, 1,  0, 7,  1, 8,  3, 8,  4, 7,  4, 5,  3, 5,  -2 },
  { 'H',  0, 0,  0, 8,  -1,  4, 0,  4, 8,  -1,  0, 4,  4, 4,  -2 },
  { 'I',  1, 0,  3, 0,  -1,  2, 0,  2, 8,  -1,  1, 8,  3, 8, -2 },
  { 'J',  2, 0,  4, 0,  -1,  3, 0,  3, 7,  2, 8,  1, 8,  0, 7,  -2  },
  { 'K',  0, 0,  0, 8,  -1,  0, 4,  1, 4,  4, 0,  -1, 1, 4,  4, 8, -2 },
  { 'L',  0, 0,  0, 8,  4, 8,  -2 },
  { 'M',  0, 8,  0, 0,  2, 4,  4, 0,  4, 8,  -2 },
  { 'N',  0, 8,  0, 0,  4, 8,  4, 0,  -2 },
  { 'O',  0, 6,  0, 2,  1, 0,  3, 0,  4, 2,  4, 6,  3, 8,  1, 8,  0, 6,  -2 },
  { 'P',  0, 8,  0, 0,  3, 0,  4, 1,  4, 3,  3, 4,  0, 4,  -2 },
  { 'Q',  0, 6,  0, 2,  1, 0,  3, 0,  4, 2,  4, 6,  3, 8,  1, 8,  0, 6,  -1,  4, 8, 3, 6, -2 },
  { 'R',  0, 8,  0, 0,  3, 0,  4, 1,  4, 3,  3, 4,  0, 4,  -1,  4, 8,  2, 4,  -2 },
  { 'S',  4, 1,  3, 0,  1, 0,  0, 1,  0, 3,  1, 4,  3, 4,  4, 5,  4, 7,  3, 8,  1, 8,  0, 7,  -2 },
  { 'T',  0, 0,  4, 0,  -1,  2, 0,  2, 8,  -2 },
  { 'U',  0, 0,  0, 7,  1, 8,  3, 8,  4, 7,  4, 0, -2 },
  { 'V',  0, 0,  0, 1,  2, 8,  4, 1,  4, 0,  -2 },
  { 'W',  0, 0,  0, 8,  2, 4,  4, 8,  4, 0,  -2 },
  { 'X',  0, 0,  4, 8,  -1,  4, 0,  0, 8,  -2 },
  { 'Y',  0, 0,  2, 4,  2, 8,  -1,  2, 4,  4, 0,  -2 },
  { 'Z',  0, 0,  4, 0,  0, 8,  4, 8,  -2 },
  
  { '0',  0, 7,  0, 1,  1, 0,  3, 0,  4, 1,  4, 7,  3, 8,  1, 8,  0, 7,  4, 1,  -2 },
  { '1',  1, 1,  2, 0,  2, 8,  -1,  1, 8,  3, 8,  -2 },
  { '2',  0, 1,  1, 0,  3, 0,  4, 1,  4, 3,  3, 4,  2, 4,  0, 6,  0, 8,  4, 8,  -2 },
  { '3',  0, 1,  1, 0,  3, 0,  4, 1,  4, 3,  3, 4,  4, 5,  4, 7,  3, 8,  1, 8,  0, 7,  -1,  3, 4,  2, 4,  -2 },
  { '4',  3, 8,  3, 0,  0, 4,  0, 5,  4, 5,  -2 },
  { '5',  4, 0,  0, 0,  0, 3,  3, 3,  4, 4,  4, 7,  3, 8,  1, 8,  0, 7,  -2 },
  { '6',  4, 1,  3, 0,  1, 0,  0, 1,  0, 7,  1, 8,  3, 8,  4, 7,  4, 5,  3, 4,  0, 4,  -2 },
  { '7',  0, 0,  4, 0,  4, 1,  1, 6,  1, 8,  -2 },
  { '8',  1, 4,  0, 3,  0, 1,  1, 0,  3, 0,  4, 1,  4, 3,  3, 4,  1, 4,  0, 5,  0, 7,  1, 8,  3, 8,  4, 7,  4, 5,  3, 4, -2 },
  { '9',  0, 7,  1, 8,  3, 8,  4, 7,  4, 1,  3, 0,  1, 0,  0, 1,  0, 3,  1, 4,  4, 4,  -2 },
  
  { 0 },
};